Hey Peeps,
Been a while since i’ve been here so I feel a bit guilty asking for help but I will anyway 
I’ve been playing around with some ball mechanics and I’ve managed to develop the following bit of code to get a circle to bounce off a line quite nicely. There are some constraints though that seems to make the mechanics fall over and the ball falls through the line in some bizarre fashion.
I believe the problem is that the circle doesn’t seem to know which side of the line its on. I’m not entirely sure though!
Has anyone come across this problem before?
Cheers
package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.geom.Point;
public class GeneralRelativity extends Sprite
{
// CIRCLE CONSTANTS ==============================================
private const CIRCLE_RADIUS : uint = 20;
private const CIRCLE_RADIUS_SQR : uint = CIRCLE_RADIUS * CIRCLE_RADIUS;
// LINE CONSTANTS ================================================
private const A : Point = new Point(200,200);
private const B : Point = new Point(500,500);
// ENVIRONMENT CONSTANTS =========================================
private const GRAVITIY : Number = 1.5;
private const DRAG : Number = 0.98;
private const FRICTION : Number = 0.75;
// START CONSTANTS ===============================================
private const STARTING_VELOCITY_X : Number = -10;
private const STARTING_VELOCITY_Y : Number = 0;
private const STARTING_POSITION_X : Number = 300;
private const STARTING_POSITION_Y : Number = 100;
// OBJECT PROPERTIES =============================================
private var circle : Sprite;
private var line : Sprite;
// MOVEMENT PROPERTIES ===========================================
private var vx : Number;
private var vy : Number;
private var moveX : Number;
private var moveY : Number;
// TEST PROPERTIES ===============================================
private var hitTestPointLine : Sprite;
private var circleTrail : Sprite;
// CONSTRUCTOR ===================================================
public function GeneralRelativity()
{
reset();
addEventListener(MouseEvent.CLICK, startAnimation);
}
private function startAnimation(e : Event = null) : void
{
reset();
addEventListener(Event.ENTER_FRAME, timeStep);
}
private function timeStep(e : Event = null) : void
{
// Add enviromental forces.
vy += GRAVITIY;
vx *= DRAG;
vy *= DRAG;
// Set the virtual position
moveX += vx;
moveY += vy;
// Calculate the distance and compare for hit test.
var hitTestPoint : Point = getHitTestPoint();
var dist : Point = hitTestPoint.subtract(new Point(moveX, moveY));
var distDotDist : Number = ((dist.x * dist.x) + (dist.y * dist.y));
if (distDotDist <= CIRCLE_RADIUS_SQR )
{
// Mark where the circle hit the line
drawBlob(circleTrail, moveX, moveY, 0xFF0000, CIRCLE_RADIUS, true);
// Calculate how much to reverse the circles trajectory.
var speedSqr : Number = (vx * vx) + (vy * vy);
var oneOverSpeedSqr : Number = 1 / speedSqr;
var dotProduct : Number = ((dist.x * vx) + (dist.y * vy)) * oneOverSpeedSqr;
var undoTime : Number = Math.sqrt(((CIRCLE_RADIUS_SQR - distDotDist) * oneOverSpeedSqr) + dotProduct * dotProduct) - dotProduct;
var redoTime : Number = 1.0 - undoTime;
// Move the virtual position back to before it hit the line.
moveX -= vx * undoTime;
moveY -= vy * undoTime;
// Get a new hit test point and distance.
hitTestPointLine = new Sprite();
hitTestPoint = getHitTestPoint();
dist = hitTestPoint.subtract(new Point(moveX, moveY));
// Calculate the new trajectory.
dotProduct = 2.0 * ((dist.x * vx) + (dist.y * vy)) * (1 / CIRCLE_RADIUS_SQR);
vx -= dist.x * dotProduct;
vy -= dist.y * dotProduct;
// Loss of energy due to impact.
vx *= FRICTION;
vy *= FRICTION;
// Move the virtual position on the new trajectory.
moveX += vx * redoTime;
moveY += vy * redoTime;
// Mark where the new circle is.
drawBlob(circleTrail, moveX, moveY, 0x80FF80, CIRCLE_RADIUS, true);
}
// Move the actual ball.
circle.x = moveX;
circle.y = moveY;
}
private function reset() : void
{
// Remove everything and redraw
while (numChildren > 0) removeChildAt(0);
draw();
// Set the starting properties.
vx = STARTING_VELOCITY_X;
vy = STARTING_VELOCITY_Y;
circle.x = moveX = STARTING_POSITION_X;
circle.y = moveY = STARTING_POSITION_Y;
}
private function getHitTestPoint() : Point
{
// B - A gives the origin of the line.
var lineVector : Point = B.subtract(A);
// Circle - A gives the circle point as a projected vector.
var circleVector : Point = new Point(moveX, moveY).subtract(A);
// Calculate the dot products.
var circleVectorDotLineVector : Number = ((circleVector.x * lineVector.x) + (circleVector.y * lineVector.y));
var lineVectorDotLineVector : Number = ((lineVector.x * lineVector.x) + (lineVector.y * lineVector.y));
// Calculate the length percentage of the projected vector.
var projectedVectorLengthPercentage : Number = circleVectorDotLineVector / lineVectorDotLineVector;
// CLamp the percentage between 0 and 1.
if (projectedVectorLengthPercentage > 1) projectedVectorLengthPercentage = 1
else if (projectedVectorLengthPercentage < 0) projectedVectorLengthPercentage = 0;
// Calculates the point from A using the length percentage.
var hitTestPoint : Point = A.add(new Point(lineVector.x * projectedVectorLengthPercentage, lineVector.y * projectedVectorLengthPercentage));
// Marks the point on the line.
drawBlob(hitTestPointLine, hitTestPoint.x, hitTestPoint.y, 0xFFFF80, 3, false);
return hitTestPoint;
}
private function drawBlob(blob : Sprite, x : Number, y : Number, colour : uint, radius : uint, newSprite : Boolean) : void
{
// Draw a circle, used to marking certain points.
if (newSprite) blob = new Sprite();
blob.graphics.clear();
blob.graphics.beginFill(colour);
blob.graphics.lineStyle(0.25, 0x000000);
blob.graphics.drawCircle(x, y, radius);
blob.graphics.endFill();
if (newSprite) blob.alpha = 0.5;
addChildAt(blob, getChildIndex(line) + 1);
}
private function draw() : void
{
// Draws the line.
line = new Sprite();
line.x = A.x;
line.y = A.y;
line.graphics.lineStyle(3, 0x000000);
line.graphics.lineTo(B.x - A.x, B.y - A.y);
addChild(line);
// Draws the Circle.
circle = new Sprite();
circle.graphics.beginFill(0xA8C7FF);
circle.graphics.lineStyle(1, 0x5A94FE);
circle.graphics.drawCircle(0, 0, CIRCLE_RADIUS);
circle.graphics.endFill();
addChild(circle);
hitTestPointLine = new Sprite();
}
}
}
- Click on the ball or line to get the circle to start / reset.
- Change alter the constants if you want the line, circle starting velocity to change.
