Rotation for a movie clip...Keyboard Controls

programming flash
1

let me explain …
By pressing and holding the (KeyBoard) left and right arrow keys should rotate the MC left and Right respectively
Also by pressing the up arrow should move the MC in the direction it is pointing…
Consider the movie clip as to be a space ship…
Reply soon pleasse…
Bala…

2

for the left and right keys, you’d probably have something like this:
on the movieclip that you would like to control:

onClipEvent(enterFrame) {
    if (Key.isDown(Key.LEFT)) {
        this._rotation -= 10; //rotate the ship 10 degrees to the left
    } else if (Key.isDown(Key.RIGHT)) {
        this._rotation += 10; //rotate the ship 10 degress to the right
    }
}

i’ll brb with the code to make it move in the direction it is facing… there is a file in the flash mx help directory that shows you exactly how to do it :slight_smile: i’ll post the code anyway… bbs
hope this helps so far

3

this is the entire code, copy and pasted straight from the flash mx samples (i take no credit for this):

onClipEvent (load) {
	// declare and set initial variables
	thrust = 1;
	decay = .97;
	maxSpeed = 15;
}
onClipEvent (enterFrame) {
	// rotate right or left
	if (Key.isDown(Key.RIGHT)) {
		_rotation += 10;
	}
	if (Key.isDown(Key.LEFT)) {
		_rotation -= 10;
	}
	// 
	// 
	if (Key.isDown(Key.UP)) {
		// calculate speed and trajectory based on rotation
		xSpeed += thrust*Math.sin(_rotation*(Math.PI/180));
		ySpeed += thrust*Math.cos(_rotation*(Math.PI/180));
		flames._visible = 1;
	} else {
		// deccelerate when Up Arrow key is released
		xSpeed *= decay;
		ySpeed *= decay;
		flames._visible = 0;
	}
	// 
	// maintain speed limit
	speed = Math.sqrt((xSpeed*xSpeed)+(ySpeed*ySpeed));
	if (speed>maxSpeed) {
		xSpeed *= maxSpeed/speed;
		ySpeed *= maxSpeed/speed;
	}
	// 
	// move beetle based on calculations above
	_y -= ySpeed;
	_x += xSpeed;
	// 
	// loop to opposite side of the stage when the beetle travels off-screen
	if (_y<0) {
		_y = 232;
	}
	if (_y>232) {
		_y = 0;
	}
	if (_x<0) {
		_x = 465;
	}
	if (_x>465) {
		_x = 0;
	}
}

hope this helps you