Trouble Instantiating Class

programming flash
1

I’m trying to instantiate a custom class from the first frame of an .fla using the code:

var cd:Countdown = new Countdown();

This doesn’t work. However, when I set Countdown as the document class, the class is properly instantiated? Why is this happening? I don’t want to set Countdown as the document class. My class file is below. Help!

package {

    import flash.events.*;
    import flash.utils.*;
    import flash.text.*;
    import flash.display.*;

    public class Countdown extends MovieClip {
        private var tf:TextField;
        private var deadline:Date;
        private var millTimer:Timer;
        private var today:Date;
        private var diffDays:Number;
        private var diffHours:Number;
        private var diffMin:Number;
        private var diffSec:Number;
        private var diffMill:Number;

        public function Countdown() {
            deadline = new Date(2008,5,7,13,44,00,00);
            millTimer = new Timer(1);
            millTimer.addEventListener(TimerEvent.TIMER,onMillTimer);
            millTimer.start();
            initTextField();
        }
        private function initTextField():void {
            trace("called");
            tf = new TextField();
            tf.x = tf.y = 50;
            tf.width = 500;
            tf.autoSize = TextFieldAutoSize.LEFT;
            addChild(tf);
        }
        private function onMillTimer(e:TimerEvent):void {
            today = new Date();
            diffDays = (deadline.time - today.time)/86400000;
            diffHours = (diffDays - Math.floor(diffDays)) * 24;
            diffMin = (diffHours - Math.floor(diffHours)) * 60;
            diffSec = (diffMin - Math.floor(diffMin)) * 60;
            diffMill = (diffSec - Math.floor(diffSec)) * 1000;
            diffMill--;
            if (diffMill < 0) {
                diffMill = 999;
                diffSec--;
                if (diffSec < 0) {
                    diffSec = 59;
                    diffMin--;
                    if (diffMin < 0) {
                        diffMin = 59;
                        diffHours--;
                        if (diffHours < 0) {
                            diffHours = 24;
                            diffDays--;
                        }
                    }
                }
            }
            //trace(Math.floor(diffDays)+":"+getHour(diffHours)+":"+getMin(diffMin)+":"+getSec(diffSec)+":"+getMill(diffMill));
            tf.text = Math.floor(diffDays)+":"+getHour(diffHours)+":"+getMin(diffMin)+":"+getSec(diffSec)+":"+getMill(diffMill);
        }
        private function getHour(diffHour:Number):String {
            if (diffHour < 10) {
                return "0" + Math.floor(diffHour).toString();
            } else {
                return Math.floor(diffHour).toString();
            }
        }

        private function getMin(diffMin:Number):String {
            if (diffMin < 10) {
                return "0" + Math.floor(diffMin).toString();
            } else {
                return Math.floor(diffMin).toString();
            }
        }

        private function getSec(diffSec:Number):String {
            if (diffSec < 10) {
                return "0" + Math.floor(diffSec).toString();
            } else {
                return Math.floor(diffSec).toString();
            }
        }

        private function getMill(diffMill:Number):String {
            if (diffMill < 100 && diffMill > 9) {
                return "0" + Math.floor(diffMill).toString();
            } else if (diffMill < 10) {
                return "00" + Math.floor(diffMill).toString();
            } else {
                return Math.floor(diffMill).toString();
            }
        }
    }
}
2

You need to import the class first, then you can instantiate it.


import Countdown;
var cd:Countdown = new Countdown();
3

Oops… The class IS being instantiated but the TextField tf isn’t displaying on stage despite the fact that I’m using addChild(tf). Suggestions?

4

[QUOTE=jrutter;2337425]You need to import the class first, then you can instantiate it.


import Countdown;
var cd:Countdown = new Countdown();

[/QUOTE]

imports are only necessary when classes are defined in pacakages (and your script is not being called from within the context of the package in which the class is defined)

5

Have you used addChild to add your Countdown instance to the stage?

6

[QUOTE=bhadaway;2337430]Oops… The class IS being instantiated but the TextField tf isn’t displaying on stage despite the fact that I’m using addChild(tf). Suggestions?[/QUOTE]

You may have added the textfield but have you added the Countdown instance?

7

senocular you are a legend! thanks! still getting the hang of AS3.

8

Krilnon beat me to it :wink:

9

In that case, thanks Krilnon. I believe this is the second time you’ve helped out of bind. Much obliged.