How is this Flash Site Done?

programming flash
1

I wanted to make a site like www.georgespencer.com

Any ideas how its done?

2

With action script, maybe the flash IDE, he could have used flex or something. He might have even had a hex editor and edit the bits himself, I doubt it. He probably took his time as well.

3

[QUOTE=trex;2331169]I wanted to make a site like www.georgespencer.com

Any ideas how its done?[/QUOTE]

The set up is actually very simple.
Basically, the content is a large grid of movieclips wrapped in a container movieclip.
A mask equal to the size of the entire grid is located at the center of the stage.
The actionscript simply tweens the grid of movieclips to various positions that align the target movieclip with the mask at 100% zoom.

stop();
import gs.TweenMax;
import fl.motion.easing.*;
stage.scaleMode = StageScaleMode.NO_SCALE;

pixGroup.buttonMode = true;
pixGroup.mouseEnabled = true;
resetBtn.buttonMode = true;
resetBtn.mouseEnabled = true;

pixGroup.addEventListener(MouseEvent.CLICK, pixZoom, false, 0, true);
pixGroup.addEventListener(MouseEvent.MOUSE_OVER, pixAlpha1, false, 0, true);
pixGroup.addEventListener(MouseEvent.MOUSE_OUT, pixAlpha5, false, 0, true);
resetBtn.addEventListener(MouseEvent.CLICK, pixReset, false, 0, true);

TweenMax.allTo([pixGroup.p1,pixGroup.p2,pixGroup.p3,pixGroup.p4,pixGroup.p5,pixGroup.p6,pixGroup.p7,pixGroup.p8,pixGroup.p9], 0, {autoAlpha:.5});

var page:String = "";

function pixAlpha1(event:MouseEvent):void {
	TweenMax.to(event.target, 0, {autoAlpha:1, overwrite:true});
}

function pixAlpha5(event:MouseEvent):void {
	TweenMax.to(event.target, 2, {autoAlpha:.5, overwrite:true});
}

function pixReset(event:MouseEvent):void {
	TweenMax.to(pixGroup, 2, {scaleX:1, scaleY:1, x:250, y:150, ease:Exponential.easeOut, overwrite:false});
}

function pixZoom(event:MouseEvent):void {
	page = event.target.name;
	switch (page) {
		case "p1" :
			TweenMax.to(pixGroup, 1, {scaleX:3, scaleY:3, x:250, y:150, overwrite:true});
			break;
		case "p2" :
			TweenMax.to(pixGroup, 1, {scaleX:3, scaleY:3, x:-50, y:150, overwrite:true});
			break;
		case "p3" :
			TweenMax.to(pixGroup, 1, {scaleX:3, scaleY:3, x:-350, y:150, overwrite:true});
			break;
		case "p4" :
			TweenMax.to(pixGroup, 1, {scaleX:3, scaleY:3, x:250, y:-150, overwrite:true});
			break;
		case "p5" :
			TweenMax.to(pixGroup, 1, {scaleX:3, scaleY:3, x:-50, y:-150, overwrite:true});
			break;
		case "p6" :
			TweenMax.to(pixGroup, 1, {scaleX:3, scaleY:3, x:-350, y:-150, overwrite:true});
			break;
		case "p7" :
			TweenMax.to(pixGroup, 1, {scaleX:3, scaleY:3, x:250, y:-450, overwrite:true});
			break;
		case "p8" :
			TweenMax.to(pixGroup, 1, {scaleX:3, scaleY:3, x:-50, y:-450, overwrite:true});
			break;
		case "p9" :
			TweenMax.to(pixGroup, 1, {scaleX:3, scaleY:3, x:-350, y:-450, overwrite:true});
			break;
	}
}

Here’s the fla:[COLOR=“Blue”][U]http://www.byrographics.com/AS3/9pix/9pix.fla.zip[/U][/COLOR]
Here’s a working example:[COLOR=“blue”][U]http://www.byrographics.com/AS3/9pix/index.html[/U][/COLOR]

4

FYI: Flash 8 does not support AS3 :wink: